/*  This file downloaded from Highend3d.com
''  
''  Highend3d.com File Information:
''  
''    Script Name: create3DText v0.1
''    Author: Kai Stapel
''    Last Updated: January 26, 2005
''    Update/Change this file at:
''    http://www.highend3d.com/maya/mel/?section=utilities#3353
''  
''  Please do not alter any information above this line
''  it is generated dynamically by Highend3d.com and will
''  be changed automatically on any updates.
*/

/***************************************************************************************************
***                               MEL Script - create3DText()                                    ***
***                                                                                              ***
*** Version: 0.2 (second Release)                                                                ***
*** Author:  Kai Stapel                                                                          ***
*** Date:    02-05-2005                                                                          ***
*** Keywords: Maya, 3D text, text 3D-text, 3-dimensional text, creating text                     ***
*** Developed under Maya 6 Complete (should also work with Maya 5).                              ***
*** Description: Creates a 3-dimensional text of the passed string $str and stores the resulting ***
***              objects under a group named "Text_" + $groupName. The Font referenced by $font  ***
***              is used to create the outlines of the text. (e.g. $font="Arial|h-20|w400|c0|u") ***
*** Features: - can handle special characters including german 'Umlaute'(ä,ö,ü) and especially   ***
***             doesn't crash on colons ":" (try creating a text with Maya's textCurves          ***
***             including a colon, like this:                                                    ***
***                `textCurves -ch 0 -f "Arial|h-21|w400|c0|u" -t "colon:test"`                  ***
***             and you'll see what the problem is there)                                        ***
***           - can underline the text                                                           ***
***           - disturbing warnings are suppressed                                               *** 
***                                                                                              ***
*** Questions, bugs or suggestions: Mail to Prof_NARF@hotmail.com                                ***
***                                                                                              ***
***                                         E N J O Y !                                          ***
***                                                                                              ***
***************************************************************************************************/

global proc string create3DText( string $str , string $groupName , string $font)
{
    int $i,$j,$k,$c,$colons[],$underlined;
    string $temp[];
    string $s[];
    float $flt[];

    // ist text underlined?
    if(gmatch($font,"*|u*") == 1)
    {
        $underlined = 1;
    }
    else 
    {
        $underlined = 0;
    }
        
    // strip whitespaces
    $str = strip($str);

    if(size($groupName) == 0)
    {
        $groupName = "Text_" + $str;
    }
    else
    {
        $groupName = "Text_" + $groupName;  // create group name
    }
    $groupName = `group -n $groupName -em`;

    // is there a colon in the text?
    $c = 0; // set counter to zero
    for($i=1;$i<=size($str);$i++)
    {
        if(strcmp(substring($str,$i,$i),":") == 0)
        {
            // colon found => save colon in $colons
            $colons[$c] = $i;
            $c++;
            //print("Colon in the string at postition " + $i + ".\n");
        }
    }

    // are there any colons? if so catch the error
    if(size($colons) > 0)
    {
        catchQuiet( $s = `textCurves -ch 0 -f $font -t $str -n $groupName` );
        catchQuiet( `select $s[0]` );
        catchQuiet( `pickWalk -d down` );
        $c = 0;
        for($i=1;$i<size($str);$i++)
        {
            if($i == $colons[$c])
            {
                rename ("Char_colon_" + $i);
                $c++;
            }
            // go right if current char is no whitespace
            if(strcmp(substring($str,$i,$i)," ") != 0)
            {
                catchQuiet( `pickWalk -d right` );
            }
        }
        //print("Old string: " + $str + "\n");
        // convert all : into c
        $str = substituteAllString($str,":","c");
        //print("New string: " + $str + "\n");
    }
    else 
    {
        // create text curves
        $s = `textCurves -ch 0 -f $font -t $str -n $groupName`;
    }
    
    select $s[0];
    // rotate text
    rotate -r 270 0 0;

    // reverse curves
    $s = `ls -sl -dag -typ transform`;
    $i=1;
    $j=1;
    while($i<size($s))
    {
        select -r $s[$i];
        $temp = `ls -sl -dag -typ transform`;

        for($k=1;$k<size($temp);$k++)
        {
            $flt = `getAttr ($temp[$k] + ".worldNormal")`;
            if($flt[1] == -1)
            {
                scriptEditorInfo -e -suppressWarnings true;
                reverseCurve -ch 1 -rpo 1 $temp[$k];
                scriptEditorInfo -e -suppressWarnings false;
            }
        }
    
        $i = $i + size($temp);
	if($j < size($str))
	{	
	    $j++;
            // skip white spaces
            while(strcmp(substring($str,$j,$j)," ") == 0)
	    {
	        $j++;
	    }
        }
    }
    
    select $s[0];
    // list created text curves
    $s = `ls -sl -dag -typ transform`;
    $i=1;
    $j=1;
    while($i<size($s))
    {
        select -r $s[$i];
        $temp = `ls -sl -dag -typ transform`;

        // one curve
        if(size($temp) == 2)
        {
            select -r $temp[1];
            bev($str,$groupName,$j);
        }
        // two curves (like in o,a,i,j)
        else if(size($temp) == 3)
        {
            if(isInside($temp[2],$temp[1]) == 1)
            {
                select -r $temp[1] $temp[2];
                bev($str,$groupName,$j);
            }
            else if(isInside($temp[2],$temp[1]) == -1)
            {
                select -r $temp[1];
                bev($str,$groupName,$j);
                select -r $temp[2];
                bev($str,$groupName,$j);
            }
        }
        // three curves (like in 8,ü,Ü,&,$)
        else if(size($temp) == 4)
        {
            if((isInside($temp[2],$temp[1]) == 1) && (isInside($temp[3],$temp[1]) == 1))
            {
                select -r $temp[1] $temp[2] $temp[3];
                bev($str,$groupName,$j);
            }
            else if((isInside($temp[2],$temp[1]) == -1) && (isInside($temp[3],$temp[1]) == -1) && (isInside($temp[3],$temp[2]) == -1))
            {
                select -r $temp[1];
                bev($str,$groupName,$j);
                select -r $temp[2];
                bev($str,$groupName,$j);
                select -r $temp[3];
                bev($str,$groupName,$j);
            }
            // TODO: any other combination of the curves
        }
        // four curves (like in ä,ö,Ä,Ö)
        else if(size($temp) == 5)
        {
            if((isInside($temp[2],$temp[1]) == 1) && (isInside($temp[3],$temp[1]) == -1) && (isInside($temp[4],$temp[1]) == -1))
            {
                select -r $temp[1] $temp[2];
                bev($str,$groupName,$j);
                select -r $temp[3];
                bev($str,$groupName,$j);
                select -r $temp[4];
                bev($str,$groupName,$j);
            }
        }
        
        $i = $i + size($temp);
	if($j < size($str))
	{	
	    $j++;
            // skip white spaces
            while(strcmp(substring($str,$j,$j)," ") == 0)
	    {
	        $j++;
	    }
        }
    }

    if($underlined == 1)
    {
        $flt[0] = `getAttr ($groupName + ".boundingBoxMinX")`;
        $flt[1] = `getAttr ($groupName + ".boundingBoxMaxX")`;
        $flt[2] = `getAttr ($groupName + ".boundingBoxMaxZ")`;
        $temp[0] = `curve -d 1 -per on -p $flt[0] 0 ($flt[2]+0.1) -p $flt[1] 0 ($flt[2]+0.1) -p $flt[1] 0 ($flt[2]+0.5) -p $flt[0] 0 ($flt[2]+0.5) -p $flt[0] 0 ($flt[2]+0.1) -k 0 -k 1 -k 2 -k 3 -k 4 -n "underline"`;
        scriptEditorInfo -e -suppressWarnings true;
        reverseCurve -ch 1 -rpo 1 $temp[0];
        scriptEditorInfo -e -suppressWarnings false;
        select $temp[0];
        bev("u",$groupName,1);
        delete $temp[0];
    }

    // delete curves
    select -r $s[0];
    delete;
  
    // move to center
    select $groupName;
    CenterPivot;
    DeleteHistory;
    move -r 0 -0.1 0 $groupName.scalePivot;
    move -spr -a 0 0 0;
    //scale -r 0.3 0.3 0.3;
    makeIdentity -apply true -t 1 -s 1 -r 1;
    return $groupName;
}

// bevels text curves to text volume
global proc bev( string $str, string $groupName, int $i )
{
    string $temp = "Char_" + substring($str,$i,$i);
    bevelPlus -ch true -range false -po 1 -ns 3 -js true -w 0.04 -d 0.04 -ed 0.2 -cap 3 -os 2 -is 5 -pom 2 -pet 2 -pes 1 -pct 3 -pcs 4;
    $temp = `rename $temp`;
    parent $temp $groupName;
}

/********* tests if curve1 is inside curve2       *******/
/********* returns: 1 curve1 is inside curve2     *******/
/*********          0 curve1 and curve2 intersect *******/
/*********         -1 curve1 is outside curve2    *******/

global proc int isInside( string $curve1, string $curve2 )
{
    string $s,$str[],$temp1[],$temp2[];
    float $center[],$bbmin[],$bbmax[];
    
    // check if $curve1 and $curve2 are nurbsCurves
    if(!objExists($curve1) || !objExists($curve2))
    {
        error -sl true "The passed parameters are no curves!";
    }
    $temp1 = `listRelatives -c $curve1`;
    $temp2 = `listRelatives -c $curve2`;
    $str = `ls -s $curve1 $curve2 $temp1 $temp2`;
    if((size($str) < 2) || !`objectType -isType "nurbsCurve" $str[0]` || !`objectType -isType "nurbsCurve" $str[1]`)
    {
        error -sl true "The passed parameters are no curves!";
    }
    
    // suppress warnings if there is no intersection
    scriptEditorInfo -e -suppressWarnings true;
    
    $s = `curveIntersect -ud true -d 0 1 0 $curve1 $curve2`;
    
    // turn warnings back on
    scriptEditorInfo -e -suppressWarnings false;
    
    // intersection
    if(size($s) > 0)
    {
        return 0;
    }
    else
    {
        $center = `getAttr ($curve1 + ".center")`;
        $bbmin = `getAttr ($curve2 + ".boundingBoxMin")`;
        $bbmax = `getAttr ($curve2 + ".boundingBoxMax")`;
        // is $curve1 inside $curve2 ?
        if($center[0] >= $bbmin[0] && $center[1] >= $bbmin[1] && $center[2] >= $bbmin[2] &&
           $center[0] <= $bbmax[0] && $center[1] <= $bbmax[1] && $center[2] <= $bbmax[2])
        {
            return 1;
        }
        // or is $curve1 outside $curve2 ?
        else
        {
            return -1;
        }
    }

    return 0;
}